***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Nov 10, 2017                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJA3404 D  G  S
rg     G    1t    1
m1     2     1    3    3    dmos    L=1u   W=1u
.model dmos nmos ( 
+  vto = 1.5
+   kp = 8
+ tnom = 25
+level = 3)   
cgs	1t	 3	50p	ic = 0
rd	 D	 4	1.5e-3	tc=2e-3
dds	 3	 4	dds
.model dds d (bv = 33  ibv = 0.25e-6  tbv1 = 9.2e-4  m=0.36  cjo=32p  vj=0.8   is = 5e-8   n = 1.863	  rs = 0.02   )
e1	1 3 table { v(1t, S) } 
+ ((0   , 0   )
+  (1.00, 1   )
+  (1.50, 1.50)
+  (2.00, 2.0 )
+  (2.50, 2.5 )
+  (3.00, 3   )
+  (3.50, 3.65)
+  (4.5 , 5)
+  (5.00, 5.35)
+  (6.00, 5.95)
+  (8.00, 6.75)
+  (10.0, 7.2 )) 
dbody   3   D    dbody
gds D S value = {8e-3*(temp-25)*limit((v(G,S)-1),0,2.5)*limit(v(D,S),0,1)}
.model   dbody    d(is = 5e-8   n = 1.863	  rs = 0.02   tt = 100n   vj = 0.8   eg = 1.102 )
ra      4    2    1.5e-3  tc=2e-3
rs      3    5    1e-4
ls      5    S   0.0001n
m2      1t    8    6    6   inter
e2      8    6    4    1t   2
.model	inter	nmos(vto=0	kp=10	level=1) 
cgdmax  7    4    10p ic=0
rcgd    7    4    10meg
dgd     6    4    dgd
rdgd    4    6    10meg
.model     dgd    d(m=0.3   cjo=68p   vj=0.4)
m3      7    9    1t    1t   inter
e3      9    1t    4    1   -2
.ends
*$
